Akademie der Wissenschaften und der Literatur | Digitale Akademie

Graphentechnologien in den Digitalen Geisteswissenschaften

Erste Schritte in der Graphenwelt

Andreas Kuczera | https://studiengang-digitale-methodik.pages.gitlab.rlp.net/modul-5/5c/slides/graphentechnologien/
Quellen der Folien auf gitlab.rlp.net Beispielprojekte: NeG | RI | DTA
CC-BY 4.0

Gliederung

1. Beispielgraph
2. Neo4j
3. Mein erster Knoten
4. Verknüpfungen und Auswertung
5. Import von Daten aus Google-Drive

01b

Erläuterungen

• Der Beispielgraph zeigt oben einen Knoten (engl. Nodes) vom Typ Person mit der Eigenschaft Name. Diese hat den Wert "Karl der Große".
• Links unten ist ein weiter Knoten vom Typ Person mit dem Namen "Einhard".
• Rechts unten ist ein Knoten vom Typ Buch und dem Titel "Vita Karoli Magni".
• Die Kanten (engl. Edges) geben an, dass Karl der Große Einhard kannte, Einhard ca. 828-830 das Buch "Vita Karoli Magni" schrieb und Karl der Große in dem Buch vorkommt.

02

Neo4j

• Download von Neo4j-Desktop von https://neo4j.com/download/
• Oder eine Sandbox erstellen
  
• Neo4j-Desktop starten bzw. Browser aufrufen
  (http://localhost:7474)
• Links oben sind Informationen zu Struktur der Datenbank und Beispielbefehle. Im dritten Tab findet sich die Dokumentation
• Im rechten Bereich befindet sich das Eingabefeld für die Befehle und das Ergebnisfenster
• Erstes Login mit neo4j/neo4j. Anschließend eigenes Passwort vergeben. Merken !

03a

Mein erster Knoten

• Link zur gemeinsamen Arbeitsdatenbank

  Login: neo4j

  Passwort: |Rpmx18YvM6Zn-

• Datenbank leeren:

  MATCH (n) DETACH DELETE n; 
      CALL apoc.schema.assert({},{},true) YIELD label, key
  RETURN *;
  

03b

Mein erster Knoten

• Erstellt einen Knoten vom Typ Person mit einem Label und liefert das erstellte als Ergebnis zurück:

  CREATE (n:Person) RETURN n;
  

03c

Mein erster Knoten

• Erstellt einen Knoten mit Label und einer Eigenschaft (auch mehrfach):

  CREATE (n:Person {nachname:'Kuczera'})
  RETURN n;
  

• Löschen eines Knotens:

  MATCH (n:Person {nachname:'Kuczera'})
  DELETE n;
  

• Knoten mit Label und einer Eigenschaft erstellen, falls es ihn noch nicht gibt:

  MERGE (n:Person {nachname:'Kuczera'})
  RETURN n;
  

03d

Mein erster Knoten

• Ergänzt einen Personenknoten um die Eigenschaft Geburtsort:

  MATCH (n:Person {nachname:'Kuczera'})
  SET n.geburtsort = 'Giessen'
  RETURN n;
  

• Zeige mir alle Personen, mit einem bestimmen Nachnamen:

  MATCH (n:Person)
  WHERE n.nachname = 'Kuczera'
  RETURN n;
  

• Zeige mir alle Personen, in denen der Buchstabe 'r' in der Eigenschaft Nachname vorkommt:

  MATCH (n:Person)
  WHERE n.nachname =~ '.*r.*'
  RETURN n;
  

04

Verknüpfungen und Auswertung

• Ergänzt eine weitere Person:

  MERGE (n:Person {nachname:'Schrade', geburtsort:'Worms'}) RETURN *;
  

• Ergänzt eine Verküpfung zwischen zwei Personen

  MATCH (n1:Person {nachname:'Kuczera'})
  MATCH (n2:Person {nachname:'Schrade'})
  MERGE (n1)-[:MEIN_LINKER_NACHBAR]->(n2)
  RETURN *;
  

• Zeige mir alle Personen neben Herrn Kuczera:

  MATCH (n:Person {nachname:'Kuczera'})-[:MEIN_LINKER_NACHBAR]-(m:Person)
  RETURN *;
  

05

LOAD CSV aus dem Google Drive

• Google-Tabelle

• LOAD CSV WITH HEADERS FROM
  "https://docs.google.com/spreadsheets/d/1q1n2TqH4blCm0LU3GFisCFLU91f9hm7TROk4eh0auyw/export?format=csv&id=1q1n2TqH4blCm0LU3GFisCFLU91f9hm7TROk4eh0auyw&gid=0"
  AS line FIELDTERMINATOR ','
  WITH line
  WHERE line.nachname IS NOT NULL
  CREATE (p1:Person {pid:line.nr, vorname:line.vorname, nachname:line.nachname, geschlecht:line.geschlecht, geburtsort:line.geburtsort, geburtsjahr:line.geburtsjahr, linkerNachbar:line.linkerNachbar, kennt:line.kennt, fach1:line.fach1, fach2:line.fach2, programmiersprachen:line.programmiersprachen, erfahrungDatenmodellierung:line.erfahrungDatenmodellierung, sprachen:line.sprachen, vertiefung:line.vertiefung, socialMedia:line.socialMedia})
  RETURN *;

• LOAD CSV WITH HEADERS FROM
  "https://docs.google.com/spreadsheets/d/1q1n2TqH4blCm0LU3GFisCFLU91f9hm7TROk4eh0auyw/export?format=csv&id=1q1n2TqH4blCm0LU3GFisCFLU91f9hm7TROk4eh0auyw&gid=0"
  AS line FIELDTERMINATOR ',' WITH line WHERE line.kennt IS NOT NULL
  MATCH (p1:Person {pid:line.nr})
  WITH line, p1, split(line.kennt,",") AS kennen
  MATCH (p3:Person) WHERE p3.pid in kennen
  MERGE (p1)-[:KENNT]->(p3)
  WITH p1, line
  MATCH (p2:Person {pid:line.linkerNachbar})
  MERGE (p1)-[:MEIN_LINKER_NACHBAR]->(p2)
  RETURN *;

06

Abfragen und Übungen

• In welchem Ort sind die meisten Personen geboren ?

  MATCH (n:Person)
  RETURN n.geburtsort, count(*) as count, collect(n.nachname) as nachname
  ORDER BY count DESC;
  

• In welchem Jahrzehnt wurden die meisten Seminarteilnehmer geboren ?

  MATCH (n:Person)
  RETURN left(n.geburtsjahr, 3) + '0' AS Jahrzehnt, count(*) as Anzahl, collect(n.nachname) as nachname
  ORDER BY Anzahl DESC;
  

06

Abfragen und Übungen

• Gibt es eine Verbindung zwischen zwei Personen ?

  // shortest_path
  MATCH
  (p1:Person { nachname:'Kuczera' }),
  (p2:Person { nachname:'Schrade' }),
  p = shortestPath((p1)-[*..25]-(p2))
  RETURN p;
  

• Pfade zwischen Personen, die 1993 und 1995 geboren wurden ?

  MATCH
  (p1:Person),
  (p2:Person),
  p = shortestPath((p1)-[*..25]-(p2))
  WHERE p1.geburtsjahr = '1992'
  AND p2.geburtsjahr = '1995'
  AND p1 <> p2
  RETURN p;
  

07

Graph-Refactoring

• Geburtsorte explizit erstellen

  // Geburtsorte aus der Property geburtsort erstellen
    MATCH (n:Person)
    WHERE n.geburtsort IS NOT NULL
    MERGE (o:Ort {name:n.geburtsort})
    MERGE (o)<-[:GEBOREN_IN]-(n)
    RETURN *;
  

• Fächer explizit erstellen

  // Fächer aus den Properties fach1 und fach2 erstellen
    MATCH (n:Person) WHERE n.fach1 IS NOT NULL
    MERGE (f1:Fach {name:n.fach1})
    MERGE (f1)<-[:STUDIUM]-(n)
    RETURN *;
  
    MATCH (n:Person) WHERE n.fach2 IS NOT NULL
    MERGE (f2:Fach {name:n.fach2})
    MERGE (f2)<-[:STUDIUM]-(n)
    RETURN *;
  

08

Graph-Refactoring

• Programmiersprachen explizit erstellen

  // Programmiersprachen aus der Property programmiersprachen erstellen
        MATCH (n:Person)
        WHERE n.programmiersprachen IS NOT NULL
          FOREACH ( j in split(n.programmiersprachen, ",") |
          MERGE (t:Programmiersprache {name:trim(j)})
          MERGE (t)<-[:KANN]-(n)
          );
      

09

Graph-Auswertung

• Welche Fächer sind am beliebtesten ?

  // Beliebtestes Fach
        MATCH (p:Person)-[:STUDIUM]-(f:Fach)
        RETURN f.name AS Fach, count(*) AS Anzahl
        ORDER BY Anzahl DESC;
      

• Gibt es einen Zusammenhang zwischen Geburtsort und Fachwahl ?

  // Geburtsort und Fächer ausgezählt
        MATCH (o:Ort)<-[:GEBOREN_IN]-(p:Person)-[:STUDIUM]-(f:Fach)
        RETURN o.name AS Ort, f.name AS Fach, count(*) AS Anzahl
        ORDER BY Anzahl DESC;
      

10

DIKW-Pyramide

Akademie der Wissenschaften und der Literatur | Digitale Akademie

Vielen Dank für Ihre Aufmerksamkeit

Andreas Kuczera | https://studiengang-digitale-methodik.pages.gitlab.rlp.net/modul-5/5c/slides/graphentechnologien/
Beispielprojekte: NeG | RI | DTA
CC-BY 4.0